Command Redirection, Pipes

Syntax : Redirection

   command  >  filename       Redirect command output to a file

   command  >> filename       APPEND into a file

   command  <  filename       Type a text file and pass the text to command

   commandA  |  commandB      Pipe the output from commandA into commandB

   command  &  command        Perform the first command & then perform the second


   command  2> filename       Redirect any error message into a file
  (command) 2> filename       Redirect any CMD.exe error into a file
   command  > file 2>&1       Redirect output and errors to one file
   command  > fileA 2> fileB  Redirect output and errors to separate files

   command  2>&1 >filename    This will fail!

Redirect to NUL (hide errors)

   command  2> nul            Redirect error messages to NUL
   command  >nul 2>&1         Redirect error and information messages to NUL
   command  >filename 2> nul  Redirect info to file but suppress error
  (command) >filename 2> nul  Redirect info to file but suppress CMD.exe errors

Note, any long filenames must be surrounded in "double quotes". A CMD error is an error raised by the command processor itself rather than the program/command.

Redirection with > or 2> will overwrite any existing file.

You can also redirect to a printer with > PRN or >LPT1

To prevent any of the above characters from causing redirection prefix with a caret ^

Examples of redirection:

   DIR >MyFileListing.txt
   
   DIR /o:n >"Another list of Files.txt"

   ECHO y| DEL *.txt

   ECHO Some text ^<html tag^> more text
   
   MEM /C >>MemLog.txt

   Date /T >>MemLog.txt

   SORT < MyTextFile.txt

   SET _output=%_missing% 2>nul

   DIR C:\ >List_of_C.txt 2>errorlog.txt
   
   FIND /i "Jones" < names.txt >logfile.txt

   DIR C:\ >List_of_C.txt & DIR D:\ >List_of_D.txt

   ECHO DIR C:\ ^> c:\logfile.txt >NewScript.cmd

   (TYPE logfile.txt >> newfile.txt) 2>nul

Related:

Syntax
Q245031 - Error when using the | pipe symbol

Linux BASH equivalent commands:

Redirection - Spooling output to a file, piping input

Simon Sheppard
SS64.com